;;; grocy.el --- Grocy frontend -*- lexical-binding: t; -*-
;;
;; Copyright (C) 2024 Óscar Nájera
;;
;; Author: Óscar Nájera <hi@oscarnajera.com>
;; Maintainer: Óscar Nájera <hi@oscarnajera.com>
;; Created: October 19, 2024
;; Modified: October 19, 2024
;; Version: 0.0.1
;; Keywords: abbrev bib c calendar comm convenience data docs emulations extensions faces files frames games hardware help hypermedia i18n internal languages lisp local maint mail matching mouse multimedia news outlines processes terminals tex tools unix vc wp
;; Homepage: https://github.com/titan/grocy
;; Package-Requires: ((emacs "29.1"))
;;
;; This file is not part of GNU Emacs.
;;
;;; Commentary:
;;
;;  Grocy Emacs frontend
;;
;;; Code:

(require 'url)
(require 'dash)
(require 'yaml)
(require 'yaml-mode)

;; Silence byte-compiler.
(defvar url-http-end-of-headers)

(defvar grocy-units)
(defvar grocy-locations)

(defcustom grocy-server ""
  "Grocy main domain."
  :type 'string
  :group 'grocy)

(defcustom grocy-api-key ""
  "API key to authenticate to grocy server."
  :type 'string
  :group 'grocy)

(defun grocy--request (endpoint callback &optional method data)
  "Do a GET request to api ENDPOINT and call CALLBACK on the resulting buffer.
Set METHOD to other request types and include the already encoded DATA."
  (let ((url-request-method (or method "GET"))
        (url-request-extra-headers
         `(("GROCY-API-KEY" . ,grocy-api-key)
           ("accept" . "application/json")
           ("Content-Type" . "application/json")))
        (url-request-data data))
    (url-retrieve
     (concat grocy-server "/api/" endpoint)
     callback)))

(defun grocy-update-units ()
  "Update localdb with units."
  (grocy--request
   "objects/quantity_units"
   (lambda (_status)
     (goto-char url-http-end-of-headers)
     (let ((result (make-hash-table)))
       (mapc
        (lambda (unit)
          (-let (((&hash "id" "name" "name_plural") unit))
            (puthash id
                     (cons name name_plural)
                     result)))
        (json-parse-buffer))
       (setq grocy-units result)))))

(defun grocy-update-locations ()
  "Update localdb with locations."
  (grocy--request
   "objects/locations"
   (lambda (_status)
     (goto-char url-http-end-of-headers)
     (let ((result (make-hash-table)))
       (mapc
        (lambda (location)
          (-let (((&plist :id) location))
            (puthash id (cdddr location)
                     result)))
        (json-parse-buffer :object-type 'plist))
       (setq grocy-locations result)))))

(grocy-update-units)
(grocy-update-locations)

(defun grocy-stock--row (row)
  "Compose ROW into tabulated entry for stock view."
  (-let* (((&alist 'amount 'amount_opened 'product 'best_before_date) row)
          ((&alist 'name 'qu_id_stock) product)
          (amount
           (concat (number-to-string amount)
                   " "
                   (funcall
                    (if (= 1 amount) #'car #'cdr)
                    (gethash qu_id_stock grocy-units))
                   (when (< 0 amount_opened)
                     (concat " / "
                             (number-to-string amount_opened)
                             " open")))))
    (list row (vector best_before_date amount name))))

(defun grocy-stock ()
  "Show the grocery stock."
  (interactive)
  (grocy--request
   "stock"
   (lambda (_status)
     (goto-char url-http-end-of-headers)
     (let ((result (json-parse-buffer :object-type 'alist)))
       (with-current-buffer (get-buffer-create "Grocy stock")
         (tabulated-list-mode)
         (setq tabulated-list-format [("Next due" 12 t)
                                      ("Amount" 20 t)
                                      ("Product" 20 t)]
               ;; tabulated-list-padding 2
               tabulated-list-sort-key '("Next due"))

         (thread-last
           (cl-map 'list #'grocy-stock--row result)
           (setq tabulated-list-entries))
         (tabulated-list-init-header)
         (tabulated-list-print)
         (display-buffer (current-buffer)))))))

(defun grocy-products ()
  "Render tabulated list view of products."
  (interactive)
  (grocy--request
   "objects/products"
   (lambda (_status)
     (goto-char url-http-end-of-headers)
     (let ((result (json-parse-buffer)))
       (with-current-buffer (get-buffer-create "Grocy products")
         (tabulated-list-mode)
         (setq tabulated-list-format [("Name" 40 t)
                                      ("Location" 15 t)
                                      ("Unit" 8 t)
                                      ("min stock" 5 t)]
               tabulated-list-sort-key '("Name"))

         (thread-last
           (cl-map 'list
                   (lambda (product)
                     (-let (((&hash "name" "location_id" "qu_id_stock"
                                    "min_stock_amount") product))
                       (list product
                             (vector name
                                     (car (gethash location_id grocy-locations))
                                     (car (gethash qu_id_stock grocy-units))
                                     (number-to-string min_stock_amount)))))
                   result)
           (setq tabulated-list-entries))
         (local-set-key "e" #'grocy-update-product)
         (tabulated-list-init-header)
         (tabulated-list-print)
         (display-buffer (current-buffer)))))))

(defun grocy-update-product ()
  "Update form for currently selected product."
  (interactive)
  (let* ((product (tabulated-list-get-id))
         (id (gethash "id" product)))
    (with-current-buffer (get-buffer-create "* Grocy update product *")
      (erase-buffer)
      (thread-first
        product
        (map-into 'alist)
        (pp (current-buffer)))
      (emacs-lisp-mode)
      (keymap-local-set "C-c C-c"
                        (lambda () (interactive)
                          (grocy-update-object (format "products/%d" id))
                          (kill-buffer)))
      (switch-to-buffer (current-buffer)))))

(defun grocy-buffer-obj->json (buffer)
  "On the BUFFER read Lisp object and encode it into json."
  (let ((json-null :null))
    (with-current-buffer buffer
      (goto-char (point-min))
      (thread-first
        (current-buffer)
        (read)
        (json-encode)
        (encode-coding-string 'utf-8)))))

(defun grocy-buffer-yaml->json (buffer)
  "Read the YAML on BUFFER and encode it to json."
  (with-current-buffer buffer
    (thread-first
      (buffer-string)
      (yaml-parse-string)
      (json-encode)
      (encode-coding-string 'utf-8))) )

(defun grocy-update-object (object-endpoint)
  "Update on the OBJECT-ENDPOINT with the Lisp object on buffer."
  (grocy--request
   (format "objects/%s" object-endpoint)
   (lambda (status)
     (when status
       (message "%S\n%S" status (buffer-string))))
   "PUT"
   (grocy-buffer-obj->json (current-buffer))))

(defun grocy-new-product ()
  (interactive)
  (with-current-buffer (get-buffer-create  "* Grocy new product *")
    (erase-buffer)
    (yaml-mode)
    (keymap-local-set
     "C-c C-c"
     (lambda () (interactive)
       (grocy--request
        "objects/products"
        (lambda (status)
          (message "%S\n%S" status (buffer-string)))
        "POST"
        (grocy-buffer-yaml->json (current-buffer)))))
    (insert "name: \n# ")
    (maphash (lambda (key val) (insert (format "%d:'%s' " key (car val)))) grocy-locations)
    (insert "\nlocation_id: \n\# ")
    (maphash (lambda (key val) (insert (format "%d:'%s' " key (car val)))) grocy-units)
    (insert "\nqu_id_stock: 3
qu_id_purchase: 3
qu_id_consume: 3
qu_id_price: 3

min_stock_amount: 0
default_best_before_days: -1"))
  (grocy-buffer-yaml->json (current-buffer)))

(provide 'grocy)
;;; grocy.el ends here